home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
84xx
/
8411.d64
/
exsort demo
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
3KB
|
118 lines
0 IFK=0THENK=1:LOAD"EXSORT?",8,1:REM LADEN VON EXSORT
1 SYS49400:REM STARTEN VON EXSORT
100 REM ***********************
110 REM *** EXSORT DEMO ***
120 REM ***********************
130 REM
140 REM ******************
150 REM * 1.BEFEHL: "SO" *
160 REM ******************
165 PRINT"[147][197]RSTER [194]EFEHL: 'SO'"
170 INPUT"[218]AHL DER ZU SORTIERENDEN [197]LEMENTE";A
175 PRINT"[193]NFUELLEN DES [198]ELDES 'ZA' MIT [218]UFALLS- ZAHLEN"
180 DIMZA(A)
190 REM *** DAS FELD ZA WIRD MIT ZUFALLSZAHLEN BELEGT ***
200 FORS=1TOA
210 :ZA(S)=RND(1)*10000-5000
220 NEXTS
230 IT=TI:REM ZEIT SPEICHERN
240 PRINT"[211]ORTIERBEGINN"
250 REM
260 REM *** AUFRUF DES BEFEHLS "SO" ***
270 SO,ZA,1,A,1
280 REM SO = BEFEHL
290 REM ZA = FELDNAME
300 REM 1 = ANFANGSINDEX
310 REM A = ENDINDEX
320 REM 1 = SORTIERUNGSRICHTUNG(AUFSTEIGEND)
330 REM
340 IT=TI-IT
350 PRINT"[211]ORTIERENDE"
355 FORS=1TO1000:NEXTS
360 REM *** AUSGABE DER SORTIERTEN ELEMENTE ***
370 FORS=1TOA
380 :PRINTS,TAB(6)ZA(S)
390 NEXTS
400 PRINT"[218]EIT:"IT/60"SEC"
410 PRINT"BITTE [212]ASTE DRUECKEN"
420 GETT$:IFT$=""THEN420
430 REM
440 REM ******************
450 REM * 2.BEFEHL: "SE" *
460 REM ******************
470 REM
480 CLR:DIMFE$(10000)
485 PRINT"[147][218]WEITER [194]EFEHL 'SE'"
490 REM ** IN 50 BELIEBIGE ELEMENTE **
500 REM ** DES FELDES FE$ WIRD DAS **
510 REM ** WORT "HALLO" GESCHRIEBEN **
520 REM
525 PRINT"[201]N 50 BELIEBIGE [197]LEMENTE VON FE$ WIRD 'HALLO' GESCHRIEBEN"
530 FORS=1TO50
540 :FE$(RND(1)*10000)="HALLO"
550 NEXTS
560 PRINT"[201]N FOLGENDEM ELEMENTEN STEHT 'HALLO':"
570 REM
580 REM ** AUSDRUCKEN JEDES INDEXES **
590 REM ** IN DEM "HALLO" STEHT **
600 REM
610 IN=-1:IT=TI
620 REM ** AUFRUF DES BEFEHLS "SE" **
630 SE,FE$,IN+1,10000,"HALLO"
640 REM SE = BEFEHL
650 REM FE$ = FELDNAME
660 REM IN+1 = ANFANGSINDEX
670 REM 10000 = ENDINDEX
680 REM "HALLO" = ELEMENT
690 REM ** BEI RUECKKEHR AUS "SE" **
700 REM ** ENTHAELT "IN" DEN INDEX **
710 REM ** ODER (WENN DAS ELEMENT **
720 REM ** NICHT GEFUNDEN WURDE) **
730 REM ** DEN WERT -1 **
740 IFIN=-1ORIN=10000THEN760
750 PRINTIN,:GOTO630
760 PRINT:PRINT"[218]EIT:"(TI-IT)/60"SEC"
770 PRINT"BITTE [212]ASTE DRUECKEN"
780 GETT$:IFT$=""THEN780
790 REM
800 REM ****************************
810 REM * 1.BEFEHL 'SO' MIT OPTION *
820 REM ****************************
830 REM
835 PRINT"[147][197]RSTER [194]EFEHL MIT OPTION"
840 DATANULL,ZWEI,VIER,SECHS,ACHT,ZEHN,EINS,DREI,FUENF,SIEBEN,NEUN
850 DATA0,2,4,6,8,10,1,3,5,7,9
860 CLR:DIMNR(10),NR$(10)
870 REM ** EINLESEN IN FELD NR$ **
880 FORS=0TO10
890 :READX$:NR$(S)=X$
900 NEXTS
910 REM ** EINLESEN IN FELD NR **
920 FORS=0TO10
930 :READX:NR(S)=X
940 NEXTS
950 REM ** AUSGABE FELD VOR SORTIERUNG **
960 PRINT"[201]NDEX NR$ VORHER NR * NR$ NACHHER NR"
970 FORS=0TO10
980 :PRINTS;TAB(6)NR$(S)TAB(16)NR(S)
990 NEXTS
1000 REM ** AUFRUF DES BEFEHL "SO" MIT OPTION **
1010 SO,NR$,0,10,0,NR
1020 REM SO = BEFEHL
1030 REM NR$ = FELDNAME 1
1040 REM 0 = ANFANGSINDEX
1050 REM 10 = ENDINDEX
1060 REM 0 = SORTIERUNGSRICHUTNG(ABSTEIGEND)
1070 REM NR = FELDNAME 2
1080 REM
1090 PRINT"[211]ORTIEREN VON NR$ ABSTEIGEND"
1095 PRINT"NR WIRD ENTSPRECHEND MITSORTIERT"
1097 PRINT"BITTE [212]ASTE DRUECKEN"
1098 GETT$:IFT$=""THEN1098
1100 REM ** AUSGABE FELD NACH SORTIERUNG **
1110 PRINT"";
1120 FORS=0TO10
1130 :PRINTTAB(22)NR$(S)TAB(33)NR(S)
1140 NEXTS
1150 PRINT""